Confused about A000091

[Gene Smith]

If anyone has been following this, the Maple programs were still not
entirely correct, as A000089 was wrong. I'll send in a correction.

Here's a correct Maple program for the genus of X0(N):

psi := proc (n)
# Dedekind psi function
local i, j;
j := n;
for i in divisors(n) do
if isprime(i) then
j := j*(1+1/i) fi od;
j end:

nu2 := proc (n)
# number of elliptic points of order two
local i, s;
if modp(n,4) = 0 then RETURN(0) fi;
s := 1;
for i in divisors(n) do
if isprime(i) and i > 2 then
s := s*(1+legendre(-1,i)) fi od;
s end:

nu3 := proc (n)
# number of elliptic points of order three
local d, s;
if modp(n,9) = 0 then RETURN(0) fi;
s := 1;
for d in divisors(n) do
if isprime(d) then s := s*(1+legendre(-3,d)) fi od;
s end:

nupara := proc (n)
# number of parabolic cusps
local b, d;
b := 0;
for d to n do
if modp(n,d) = 0 then
b := b+phi(gcd(d,n/d)) fi od;
b end:

genx := proc (n)
# genus of X0(n)
1+1/12*psi(n)-1/4*nu2(n)-1/3*nu3(n)-1/2*nupara(n) end:
-------------- next part --------------
An HTML attachment was scrubbed...
URL: <http://list.seqfan.eu/pipermail/seqfan/attachments/20060521/792e4090/attachment-0001.htm>