[seqfan] Number of points with maximum norm n in A2, A3, A4, A5, D5

[Richard Mathar]

In some sort of response to the query in A110907  we get

%S A110907 1,12,50,108,194,300,434,588,770,972,1202,1452,1730,2028,2354,2700,3074,
%T A110907 3468,3890,4332,4802,5292,5810,6348,6914,7500,8114,8748,9410,10092,
%U A110907 10802,11532,12290,13068,13874,14700,15554,16428,17330,18252,19202
%E A110907 Extended by R. J. Mathar (mathar(AT)strw.leidenuniv.nl), Feb 03 2010
%F A110907 Conjecture: a(n) = 2*a(n-1)-2*a(n-3)+a(n-4), n>4. Conjecture: a(n) = 1+(-1)^n+12*n^2, n>0. Conjecture: g.f. = 1-2*x*(6+13*x+4*x^2+x^3)/((1+x)*(x-1)^3). [From R. J. Mathar (mathar(AT)strw.leidenuniv.nl), Feb 03 2010]
%p A110907 A110907 := proc(n) a :=0 ; for x from -n to n do for y from -n to n do for z from -n to n do if type(x+y+z,'even') then m := max( abs(x),abs(y),abs(z)) ; if m = n then a := a+1 ; end if; end if; end do ; end do ; end do ; a ; end proc: seq(A110907(n),n=0..40) ; [From R. J. Mathar (mathar(AT)strw.leidenuniv.nl), Feb 03 2010]

Can anyone verify/comment on above the following variants (?):

1) I've tried to calculate "Number of lattice points in the A2 lattice with maximum norm n"
and get A008458.

A2 := proc(n)
        pt := {} ;
        for i from -n to n do
        for j from -n to n do
                m := max( abs(i),abs(j),abs(i+j) ) ;
                if m = n then
                        pt := pt union {[i,i+j,j]} ;
                end if;
        end do ;
        end do ;
        return nops(pt) ;
end proc:

2) I've tried to calculate
"Number of lattice points in the A3 lattice with maximum norm n"
and get for n>=0
1, 18, 66, 146, 258, 402, 578, 786, 1026, 1298, 1602, 1938, 2306, 2706,
3138, 3602, 4098, 4626, 5186, 5778, 6402, 7058, 7746, 8466, 9218, 10002,
10818,

apparently a(n)= A010006(n) = A103884(2,n) = 3*a(n-1) -3*a(n-2) +a(n-3), n>3

A3 := proc(n)
        pt := {} ;
        for i from -n to n do
        for j from -2*n to 2*n do
        for k from -n to n do
                m := max( abs(i),abs(-i+j),abs(-j+k),abs(-k)) ;
                if m = n then
                        pt := pt union {[i,-i+j,-j+k,-k]} ;
                end if;
        end do ;
        end do ;
        end do ;
        return nops(pt) ;
end proc:
for n from 0 to 45 do
        printf("%d,\n", A3(n)) ;
end do ;


3) I've tried to calculate
"Number of lattice points in the A4 lattice with maximum norm n"
and get for n>=0
1, 50, 330, 1070, 2500, 4850, 8350, 13230, 19720, 28050, 38450, 51150,
apparently satisfying a(n)= 4*a(n-1) -6*a(n-2) +4*a(n-3) -a(n-4), n>4
with a(n) = 5*n*(7+23*n^2)/3, n>0, with partial sums in A083669.

A4 := proc(n)
        pt := {} ;
        for i from -n to n do
        for j from -2*n to 2*n do
        for k from -2*n to 2*n do
        for l from -n to n do
                m := max( abs(i),abs(-i+j),abs(-j+k),abs(-k+l),abs(-l)) ;
                if m = n then
                        pt := pt union {[i,-i+j,-j+k,-k+l,-l]} ;
                end if;
        end do ;
        end do ;
        end do ;
        end do ;
        return nops(pt) ;
end proc:

4) I've tried to calculate
"Number of lattice points in the A5 lattice with maximum norm n"
and get for n>=0
1, 140,1610,7580, 23330, 56252

A5 := proc(n)
        pt := {} ;
        for i from -n to n do
        for j from -n+i to n+i do
        for k from -n+j to n+j do
        for o from -n to n do
        for l from o-n to o+n do
                m := max( abs(i),abs(-i+j),abs(-j+k),abs(-k+l),abs(-l+o),abs(-o)) ;
                if m = n then
                        pt := pt union {[i,-i+j,-j+k,-k+l,-l+o,-o]} ;
                end if;
        end do ;
        end do ;
        end do ;
        end do ;
        end do ;
        return nops(pt) ;
end proc:
for n from 0 to 15 do
	printf("%d,\n", A5(n)) ;
end do ;


5) I've tried to calculate
"Number of lattice points in the D5 lattice with maximum norm n"
and get for n>=0
1,120,1442,6840,21122,51000

D5 := proc(n)
	pt := {} ;
	for o from -n to n do
	for l from -n+o to n+o do
	for k from l-n to l+n do
	for i from floor(-n-k/2) to ceil(n-k/2) do
	for j from i+k-n to i+k+n do
		m := max( abs(i+j),abs(i-j+k),abs(-k+l),abs(-l+o),abs(-o)) ;
		if m = n then
			pt := pt union {[i+j,i-j+k,-k+l,-l+o,-o]} ;
 		end if;
	end do ;
	end do ;
	end do ;
	end do ;
	end do ;
	return nops(pt) ;
end proc:

for n from 0 to 14 do
	printf("%d,\n", D5(n)) ;
end do ;

Overall, these are linear programming exercises, which are expected
to produce polynomial solutions.