[seqfan] Extending count of cyclotomic cosets to other moduli

Richard Mathar mathar at strw.leidenuniv.nl
Sat Jun 19 21:25:20 CEST 2010

http://oeis.org/classic/A006694 looks at cycles of the permutation
[2 mod 2n+1, 4 mod 2n+1, 6 mod 2n+1,..., 4n mod 2n+1]. It can
also be generated by the formula (See the Allouche article)
a(n) = sum_{d| 2n+1, d>1} A000010(d) / A002326(d/2) .

One is tempted to look at A006694 as a sequence defined for the prime p=2,
which might be generalized to other primes p according to both methods
of computation --which generate different results:

For p=3 we may define the number of cyclotomic cosets of 3 mod 3n+1,

 sum_{d| 3n+1, d>1} A000010(d) / multipl_order_3_mod_d

where the multipl_order_3_mod_n is the multiplicative order represented
by A053446 and A050975. (Index notation does not work for their staggering arguments...)
The difference between these two sequences seems to be the periodically
extended row in A093057: 1,0,1,0,1,0,1,0,1,0

For p=5 we may define the number of cyclotomic cosets of 5 mod 5n+1,

 sum_{d| 5n+1, d>1} A000010(d) / multipl_order_5_mod_d

where the multipl_order_5_mod_n is the multiplicative order represented
by A050977 and A053448.
The difference between these two sequences seems to be the periodically
extended row in A093057: 1,0,3,0,1,0,3,0,1

For p=7 we may define the number of cyclotomic cosets of 7 mod 7n+1,

 sum_{d| 7n+1, d>1} A000010(d) / multipl_order_7_mod_d

where the multipl_order_7_mod_n is the multiplicative order represented
by A050979 and A053450.
The difference between these two sequences seems to be a periodically
extended 6h row in A093057: 1,2,1,0,5,0,1,2,1,0,5,0,1,2,1,0,5,0

Generally, the "filler"-difference for the two variants of a general definition
seems to be the (p-1)st row in A093057, periodically extended.

The question that let me look at these: what is the generalization of
A137576 and/or A141232 to primes other than 2? Are these in the OEIS, for

Richard Mathar

# Maple implementation, for the books:
A093057 := proc(n,p)
        igcd((n-1) mod (p-1),p-1)-1 ;
end proc:

# The analog of the Allouche function f in "Suites infinie a repetitiones bonnes"
# Sem. Theorie Nombres Bordeaux 20 (1984) 
# http://resolver.sub.uni-goettingen.de/purl?GDZPPN002545357
f := proc(n,p)
        a := 0 ;
        for d in numtheory[divisors](p*n+1) do
                if d <> 1  then
                        a := a+numtheory[phi](d)/numtheory[order](p,d) ;
                end if:
        end do;
        a ;
end proc:

with(group) ;
# The number of disjoint cycles in the permutation
# [p mod pn+1, 2p mod pn+1, 4p mod pn+1,... p^2n mod pn+1], see A006694.
A := proc(n,p)
        a := [] ;
        for i from 1 to p*n do
                a := [op(a), (p*i) mod (p*n+1) ] ;
        end do:
        convert(a,'disjcyc') ;
        nops(%) ;
end proc:

# a fixed prime, p=2 for A006694
p := 7 ;

# Print the sequence of multiplicative orders
seq(numtheory[order](p,n),n=2..50) ;

# Print the sequence of cylotomic cosets of p mod pn+1.
# First variant of a generalization.
seq(A(n,p),n=1..50) ;

# Print a generalized Allouche function f
# Second variant of a generalization.
seq(f(n,p),n=1..50) ;

# Check that the sum of the count of cosets and a line of A093057
# is the same as the generalized Allouche function.
seq(A(n,p)+A093057(n+2,p),n=1..50) ;

More information about the SeqFan mailing list