[seqfan] Re: Sum over inverse palindromes

Richard Mathar mathar at strw.leidenuniv.nl
Wed Oct 20 17:12:44 CEST 2010


http://list.seqfan.eu/pipermail/seqfan/2010-October/006257.html says

ri> Yes, the sum converges. 
ri> The number of n-digit palindromes is O(10^(n/2)) while the reciprocal
ri> of each is less than 10^(1-n), so the sum of the reciprocals of the
ri> n-digit palindromes is O(10^(-n/2)).

This is not good. Now I feel obliged to come up with some crude estimates
of the limit -:). The partial sums over 1/p for palindromes p<= 10^d are

d   convergent
2  2.8289682539682539683
3  3.0861471861471861472
4  3.3190020006509114708
5  3.3421302129563524738
6  3.3651662022380450003
7  3.3674689702500643779
8  3.3697715736297805439
9  3.3700018324036169535
10  3.3702320909393699278
11  3.3702551167906460788
12  3.3702781426416106403
13  3.3702804452267040622
14  3.3702827478117970990


Wynn's extrapolation for the first 3, 5, 7,... of these values generates
estimators
5.54812148...
3.36995258...
3.37028506...
3.3702832624...
3.37028325945240...
3.37028325949737...

so it seems the value of is sum_{n>=2} 1/A002113(n) = 3.370283259..

# Yet another maple program (yamp):
Digits := 20 ;
# return the value of sum_p 1/p where p are dgs-digits palindromes
invPali := proc(dgs)
        local ret,dgshlf,m,p;
        ret := 0.0 ;
        dgshlf := floor(dgs/2) ;
        if type(dgs,'even') then
                # if count of digits is even, run through all dgs/2 size
                # numbers of the form 100.. up to 999..., flip them
                # to generate p, and add 1/p.
                for n from 10^(dgshlf-1) to 10^dgshlf-1 do
                        p := n*10^dgshlf+digrev(n) ;
                        ret := ret+evalf(1/p) ;
                end do:
        else
                # if count of digits is odd, run through all floor(dgs/2) size
                # numbers of the form 100.. up to 999..., flip them
                # insert m from 0 to 9 in the middle to generate p, and add 1/p.
                for n from 10^(dgshlf-1) to 10^dgshlf-1 do
                        p := n*10^(1+dgshlf)+digrev(n) ;
                        for m from 0 to 9 do
                                ret := ret+evalf(1/p) ;
                                p := p+10^dgshlf ;
                        end do:
                end do:
        end if;
        ret ;
end proc:
# start with x=sum over the 1-digit palindromes
x := add(1/n,n=1..9) :
x := evalf(x) ;
# accumulate the inverted 2-digits to 14-digit palindromes in x
for dgs from 2 to 14 do
        x := x+invPali(dgs) ;
        print(x) ;
end do:





More information about the SeqFan mailing list